Legacy_v2/Legacy_v2.pro

#-------------------------------------------------
#
# Project created by QtCreator 2018-07-12T19:45:49
#
#-------------------------------------------------

QT       += core gui network

QMAKE_LFLAGS_RELEASE += -static -static-libgcc -static-libstdc++

greaterThan(QT_MAJOR_VERSION, 4): QT += widgets

TARGET = Legacy_v2
TEMPLATE = app

CXXFLAGS += -O2 -fno-stack-limit
CONFIG += resources_big

# The following define makes your compiler emit warnings if you use
# any feature of Qt which has been marked as deprecated (the exact warnings
# depend on your compiler). Please consult the documentation of the
# deprecated API in order to know how to port your code away from it.
DEFINES += QT_DEPRECATED_WARNINGS

# You can also make your code fail to compile if you use deprecated APIs.
# In order to do so, uncomment the following line.
# You can also select to disable deprecated APIs only up to a certain version of Qt.
#DEFINES += QT_DISABLE_DEPRECATED_BEFORE=0x060000    # disables all the APIs deprecated before Qt 6.0.0


# ================================================== #
message(================QT INFO====================)
message(Qt version: $$[QT_VERSION])
message(Qt is installed in $$[QT_INSTALL_PREFIX])
# ================================================== #

message(==========BUILDING EXTERNAL RES============)
win32 {
    build_pass: CONFIG(debug, debug|release) {
        DESTDIR = $$OUT_PWD/debug
    }
    else: build_pass {
        DESTDIR = $$OUT_PWD/release
    }
}

unix {
    DESTDIR = $$OUT_PWD
}

guiRes.target = BuildResources
exists($$DESTDIR/res) {
    message("Directory $$DESTDIR/res already exists")
} else {
    guiRes.commands += $(MKDIR) \"$$DESTDIR/res\" $$escape_expand(\n\t)
    }

EXT_RES =                                                                   \
    "$$PWD/backgrounds.qrc            -o $$DESTDIR/data01.gtr"     \
    "$$PWD/common.qrc                 -o $$DESTDIR/data02.gtr"     \

for (RES, EXT_RES) {
    win32 {
        message(rcc.exe -binary $${RES})
        guiRes.commands += rcc.exe -binary $${RES} $$escape_expand(\n\t)
    }
    unix {
        guiRes.commands += rcc -binary $${RES} $$escape_expand(\n\t)
    }
}

QMAKE_EXTRA_TARGETS += guiRes
PRE_TARGETDEPS += BuildResources

# ================================================== #



SOURCES += \
        src/main.cpp \
        gui/mainwindow.cpp \
        src/menuentry.cpp \
        src/legacyapp.cpp \
        src/filesystem.cpp \
    gui/statuswidget.cpp \
    gui/rusificationwidget.cpp \
    gui/settingswidget.cpp \
    gui/newswidget.cpp \
    gui/helpwidget.cpp \
    src/networkdownloader.cpp \
    src/rusificationtreeitem.cpp

HEADERS += \
        gui/mainwindow.h \
        include/menuentry.h \
        include/legacyapp.h \
        include/filesystem.h \
    gui/statuswidget.h \
    gui/rusificationwidget.h \
    gui/settingswidget.h \
    gui/newswidget.h \
    gui/helpwidget.h \
    include/networkdownloader.h \
    include/rusificationtreeitem.h

FORMS += \
        gui/mainwindow.ui \
    gui/statuswidget.ui \
    gui/rusificationwidget.ui \
    gui/settingswidget.ui \
    gui/newswidget.ui \
    gui/helpwidget.ui

#RESOURCES += \
#    backgrounds.qrc \
#    common.qrc

win32:RC_ICONS = $$PWD/assets/appicon.ico

unix:!macx|win32: LIBS += -L$$PWD/lib/lib/ -lLotroDat_static

INCLUDEPATH += $$PWD/lib/include
INCLUDEPATH += $$PWD/include
INCLUDEPATH += $$PWD/gui

DEPENDPATH += $$PWD/lib/include

win32:!win32-g++: PRE_TARGETDEPS += $$PWD/lib/lib/LotroDat_static.lib
else:unix:!macx|win32-g++: PRE_TARGETDEPS += $$PWD/lib/lib/libLotroDat_static.a

unix:!macx|win32: LIBS += -L$$PWD/lib/Third_party/lib/ -lyaml-cpp

INCLUDEPATH += $$PWD/lib/Third_party
DEPENDPATH += $$PWD/lib/Third_party

win32:!win32-g++: PRE_TARGETDEPS += $$PWD/lib/Third_party/lib/yaml-cpp.lib
else:unix:!macx|win32-g++: PRE_TARGETDEPS += $$PWD/lib/Third_party/lib/libyaml-cpp.a

unix:!macx|win32: LIBS += -L$$PWD/lib/Third_party/lib/ -lzlibstatic

INCLUDEPATH += $$PWD/lib/Third_party
DEPENDPATH += $$PWD/lib/Third_party

win32:!win32-g++: PRE_TARGETDEPS += $$PWD/lib/Third_party/lib/zlibstatic.lib
else:unix:!macx|win32-g++: PRE_TARGETDEPS += $$PWD/lib/Third_party/lib/libzlibstatic.a

DISTFILES +=