# COMMENT THIS FOR MAKE PRODUCTION BUILDS
# DEFINES += DEBUG
# DEFINES += DEBUG_EXPIRE=1609448400 # 01.01.2021 00:00:00

# ================================================== #
message(================QT INFO====================)
message(Qt version: $$[QT_VERSION])
message(Qt is installed in $$[QT_INSTALL_PREFIX])
# ================================================== #

PROJECT_ROOT_PATH = $${PWD}/

win32: OS_SUFFIX = win32
linux-g++: OS_SUFFIX = linux

CONFIG(debug, debug|release) {
    BUILD_FLAG = debug
    LIB_SUFFIX = d
} else {
    BUILD_FLAG = release
}

LIBS_PATH = $${PROJECT_ROOT_PATH}/lib.$${OS_SUFFIX}/
INC_PATH = $${PROJECT_ROOT_PATH}/include/
IMPORT_PATH = $${PROJECT_ROOT_PATH}/import/
BIN_PATH = $${PROJECT_ROOT_PATH}/bin/$${BUILD_FLAG}/

BUILD_PATH = $${PROJECT_ROOT_PATH}/build/$${BUILD_FLAG}/$${TARGET}/
RCC_DIR = $${BUILD_PATH}/rcc/
UI_DIR = $${BUILD_PATH}/ui/
MOC_DIR = $${BUILD_PATH}/moc/
OBJECTS_DIR = $${BUILD_PATH}/obj/

LIBS += -L$${LIBS_PATH}/
INCLUDEPATH += $${INC_PATH}/
INCLUDEPATH += $${IMPORT_PATH}/

QMAKE_CXXFLAGS += -O2 -std=c++14

# The following define makes your compiler emit warnings if you use
# any feature of Qt which has been marked as deprecated (the exact warnings
# depend on your compiler). Please consult the documentation of the
# deprecated API in order to know how to port your code away from it.
DEFINES += QT_DEPRECATED_WARNINGS

# You can also make your code fail to compile if you use deprecated APIs.
# In order to do so, uncomment the following line.
# You can also select to disable deprecated APIs only up to a certain version of Qt.
#DEFINES += QT_DISABLE_DEPRECATED_BEFORE=0x060000    # disables all the APIs deprecated before Qt 6.0.0

win32 {
    # Installing manifests

    # This variable should navigate to mt.exe file
    WINDOWS_SDK_MT_EXE_PATH = C:/Program Files (x86)/Windows Kits/10/bin/10.0.18362.0/x64/mt.exe
    MANIFESTS_DIR = $$replace(PROJECT_ROOT_PATH, /, \\)\\manifests
    BUILD_DIR= $$replace(BIN_PATH, /, \\)
    QMAKE_POST_LINK = "\"$$WINDOWS_SDK_MT_EXE_PATH\" -manifest $$quote($$MANIFESTS_DIR\\$$basename(TARGET).manifest) -outputresource:$$quote($$BUILD_DIR\\$$basename(TARGET).exe;1)"
}