message(==========BUILDING EXTERNAL RES============)

guiRes.target = BuildResources
exists($$BIN_PATH/res) {
    message("Directory $$BIN_PATH/res already exists")
} else {
    message("Directory $$BIN_PATH/res DOES NOT exist")
    guiRes.commands += $(MKDIR) \"$$BIN_PATH/res\" $$escape_expand(\n\t)
}

EXT_RES =                                                                   \
    "$${PROJECT_ROOT_PATH}/resources/backgrounds.qrc            -o $$BIN_PATH/data01.gtr"     \
    "$${PROJECT_ROOT_PATH}/resources/common.qrc                 -o $$BIN_PATH/data02.gtr"     \
    "$${PROJECT_ROOT_PATH}/resources/backgrounds_advanced.qrc   -o $$BIN_PATH/data_adv.gtr"

for (RES, EXT_RES) {
    win32 {
        message(rcc.exe -binary $${RES})
        guiRes.commands += rcc.exe -binary $${RES} $$escape_expand(\n\t)
    }
    unix {
        guiRes.commands += rcc -binary $${RES} $$escape_expand(\n\t)
    }
}

QMAKE_EXTRA_TARGETS += guiRes
PRE_TARGETDEPS += BuildResources
